if TStyleManager.IsCustomStyleActive then
begin
TStyleManager.SystemHooks := TStyleManager.SystemHooks - [shDialogs]
end;

Many thanks !

Franck

if (TStyleManager::IsCustomStyleActive)
{
    TStyleManager::SystemHooks = TStyleManager::SystemHooks >> TSystemHook::shDialogs;
}

function ThemeSafeLaunchSaveDialog(SaveDialog:TSaveDialog):Boolean;
{
  @@@@@@ This is a wrapper function for SaveDialog.Execute, in order
  to work around a bug in Delphi @@@@@.
 
  This "fixes" a bug in Delphi XE10 (and possibly other versions) where if
  a VCLStyle is active the TSaveDialogs with the ofOverwritePrompt enabled
  will lock up when it asks the user to overwrite a file.  (Actually it does
  not lock up exactly, but instead displays the "Do you want to replace it?"
  prompt all tiny and scrunched up so the user can't click on the response
  buttons.
 
  This fix prevents that from happening.
 
  To use this routine, replace code like this:
 
    Result:=MySaveDialog.Execute;
 
  ...with code like this:
 
    Result:=ThemeSafeLaunchSaveDialog(MySaveDialog);
 
  For info on this bug, see:
 
    https://quality.embarcadero.com/browse/RSP-13720?jql=text%20~%20%22TSaveDialog%22
    https://forums.embarcadero.com/thread.jspa;jsessionid=5A34E74989CC46CCE41C5022E40935F5?messageID=772902
}
var
  OldOverwriteValue,DoneFlag:Boolean;
resourcestring
  sOverwriteOK1='%s already exists.';
  sOverwriteOK2='Do you want to replace it?';
begin
 
  {See if Overwrite flag was set.}
  OldOverWriteValue:=ofOverwritePrompt in SaveDialog.Options;
 
  {If the overwrite flag was not set, or if theming is not enabled,
   then just call the standard dialog as normal, since there is no Delphi bug
   to fix here.}
  if (OldOverwriteValue=False) or (TStyleManager.IsCustomStyleActive=False) then
  begin
    Result:=SaveDialog.Execute();
    exit;
  end;
 
  {If the overwrite flag was set, and we are theming, then remove that flag,
   so we can handle this condition ourselves.}
  SaveDialog.Options:=SaveDialog.Options-[ofOverwritePrompt];
 
  {Launch the dialog.}
  Result:=SaveDialog.Execute();
 
  {If the dialog was not canceled, but the file exists, then ask user if they want to overwrite.}
  if (Result=True) and FileExists(SaveDialog.FileName) then
  begin
    {Loop until either the user cancels out, or accepts the overwrite option.}
    DoneFlag:=False;
    While DoneFlag=False do
    begin
      {Prompt for overwrite.}
      if MessageDlg(Format(sOverwriteOK1,[SaveDialog.FileName])+#13+#13+sOverwriteOK2,
                    mtWarning,[mbYes,mbNo],0,mbNo)=mrYes then
      begin
        {User says okay to overwrite, so move on.}
        DoneFlag:=True;
      end
      else
      begin
        {User did not want to overwrite, so return back to dialog.}
        SaveDialog.FileName:='';       // Clear out the file name to match normal TSaveDialog behavior.
        Result:=SaveDialog.Execute();  // Re-display the dialog.
        if Result=False then
        begin
          {User canceled the dialog, so we are done here}
          DoneFlag:=True;
        end;
      end;
    end;
  end;
 
  {Restore the Overwrite value back to the dialog.}
  SaveDialog.Options:=SaveDialog.Options+[ofOverwritePrompt];
 
  {Note: An option here instead of all the mess above, is to simply disable
         themes for the dialog completely.  That can be accomplished with the
         code below, but of course the dialog is no longer themed and will clash
         with the rest of the software.
 
         HadHook:=(shDialogs in TStyleManager.SystemHooks);
         if TStyleManager.IsCustomStyleActive then TStyleManager.SystemHooks := TStyleManager.SystemHooks - [shDialogs];
         Result:=SaveDialog.Execute();
         if HadHook then TStyleManager.SystemHooks := TStyleManager.SystemHooks + [shDialogs]
  }
 
end;
 
Procedure FixStyledSaveDialogOverwritePrompt;
begin
  {@@@@@@ This is a Delphi Bug Fix.   Basically, if a Style is active, then
   TSaveDialogs go goofy when asking to overwrite an existing file, where the
   prompt for that appears as a tiny shrunk message that locks up the user's
   PC.  This fix prevents that from happening.
   See: https://forums.embarcadero.com/thread.jspa;jsessionid=5A34E74989CC46CCE41C5022E40935F5?messageID=772902
   @@@@@@}
  if TStyleManager.IsCustomStyleActive then TStyleManager.SystemHooks := TStyleManager.SystemHooks - [shDialogs]
end;