I want to make a short (fast) high pitched beep noise to help with debugging.

How do I play a sine wave at a certain frequency for a fraction of a second in Firemonkey?

I'm okay with making one version for MSWINDOWS and another for MACINTOSH if necessary.

Chris Dunn wrote:
I drop a Tmediaplayer on the form. Download a commercial free beep.mp3. and use the code below.

TMediaPlayer1.FileName := TPath.GetDocumentsPath + PathDelim + 'Sounds' + PathDelim + beep.mp3;
TMediaPlayer1.Play;

Tom Brunberg wrote:
Michael Leahy wrote:


Did you try the code at the link I gave you in my previous post?
I did, and it didn't work. It's obviously written before D2009 and a change is necessary:
The following, original string constants need to be changed to AnsiString:

   RiffId: ansistring = 'RIFF';
   WaveId: ansistring = 'WAVE';
   FmtId: ansistring = 'fmt ';
   DataId: ansistring = 'data';

I also rearranged the code, to create the sound data only once and then just reuse it, and made a
class of it.

uses
  ...  
  windows, mmsystem;
 
type
  TVolumeLevel = 0..127;
 
  TNoise = class
  private
    ms: TMemoryStream;
  public
    constructor Create(Frequency{Hz}, Duration{mSec}: Integer; Volume: TVolumeLevel);
    destructor Destroy; override;
    procedure Play;
  end;
 
implementation
  ...
{ TNoise }
 
constructor TNoise.Create(Frequency, Duration: Integer; Volume: TVolumeLevel);
var
   WaveFormatEx: TWaveFormatEx;
   i, TempInt, DataCount, RiffCount: integer;
   SoundValue: byte;
   w: double; // omega ( 2 * pi * frequency)
const
   Mono: Word = $0001;
   SampleRate: Integer = 11025; // 8000, 11025, 22050, or 44100
   RiffId: ansistring = 'RIFF';
   WaveId: ansistring = 'WAVE';
   FmtId: ansistring = 'fmt ';
   DataId: ansistring = 'data';
begin
   if Frequency > (0.6 * SampleRate) then
   begin
     ShowMessage(Format('Sample rate of %d is too Low to play a tone of %dHz',
       [SampleRate, Frequency]));
     Exit;
   end;
   with WaveFormatEx do
   begin
     wFormatTag := WAVE_FORMAT_PCM;
     nChannels := Mono;
     nSamplesPerSec := SampleRate;
     wBitsPerSample := $0008;
     nBlockAlign := (nChannels * wBitsPerSample) div 8;
     nAvgBytesPerSec := nSamplesPerSec * nBlockAlign;
     cbSize := 0;
   end;
   MS := TMemoryStream.Create;
   with MS do
   begin
     {Calculate length of sound data and of file data}
     DataCount := (Duration * SampleRate) div 1000; // sound data
     RiffCount := Length(WaveId) + Length(FmtId) + SizeOf(DWORD) +
       SizeOf(TWaveFormatEx) + Length(DataId) + SizeOf(DWORD) + DataCount; // file data
     {write out the wave header}
     Write(RiffId[1], 4); // 'RIFF'
     Write(RiffCount, SizeOf(DWORD)); // file data size
     Write(WaveId[1], Length(WaveId)); // 'WAVE'
     Write(FmtId[1], Length(FmtId)); // 'fmt '
     TempInt := SizeOf(TWaveFormatEx);
     Write(TempInt, SizeOf(DWORD)); // TWaveFormat data size
     Write(WaveFormatEx, SizeOf(TWaveFormatEx)); // WaveFormatEx record
     Write(DataId[1], Length(DataId)); // 'data'
     Write(DataCount, SizeOf(DWORD)); // sound data size
     {calculate and write out the tone signal} // now the data values
     w := 2 * Pi * Frequency; // omega
     for i := 0 to DataCount - 1 do
     begin
       SoundValue := 127 + trunc(Volume * sin(i * w / SampleRate)); // wt = w * i / SampleRate
       Write(SoundValue, SizeOf(Byte));
     end;
   end;
end;
 
destructor TNoise.Destroy;
begin
  ms.Free;
  inherited;
end;
 
procedure TNoise.Play;
begin
  sndPlaySound(MS.Memory, SND_MEMORY or SND_ASYNC);
end;
 

Note that I also changed to Async mode, not to stop the program for the sound duration.
Usage:

procedure TForm4.Button1Click(Sender: TObject);
begin
  myBeep := TNoise.Create(3800, 100, 120);
end;
 
procedure TForm4.Button2Click(Sender: TObject);
begin
  myBeep.Play;
end;

--
Tom Brunberg
firstname dot lastname at welho dot com

I tried this with XE7 and an actual Windows machine and it is much more responsive.

Perhaps my problem was with VM on the Mac slowing down the sound.

John Frazier wrote:

Reminds me of old school debugging on the Apple ][ with ASCII chr(7) [aka CTRL-G]

http://en.wikipedia.org/wiki/Bell_character

Since you are looking for custom tones, you have found you have to work a bit more for that. One thing I spotted was these libs and might have something useful for you. http://www.mitov.com/products/audiolab#overview
--
John Frazier (Embarcadero Newsgroup Admin)

John Frazier wrote:

I noticed Boian mentions FM here http://www.mitov.com/products/audiolab#downloads though it is not clear if it works on platforms other than Windows. I saw that he has introduced some Android support, might be worth asking if he has anything to test I looked briefly and this seemed promising http://mitov.com/installer/104
--
John Frazier (Embarcadero Newsgroup Admin)